MacFormat 1994 November/macformat-018.iso/Comms Spectacular/AppleTalk Remote Access/Avtek ARA Scripts V1.1/Avtek Meg DataFax CD900

Text File | 1994-04-06 | 2.5 KB | 179 lines | [mlts/slnk]

! "Avtek Mega DataFax CD900 - 6th April 1994 - NJS - v1.1
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 2400, 0, 8, 1
DTRset
!
! first recall the factory configuration
!
matchclr
settries 0
matchstr 1 3 "OK"
@LABEL 2
write "AT&F\13"
matchread 30
inctries
iftries 2 59
jump 2
!
! Next, Set up the default configuration and Echo off
!
@LABEL 3
matchstr 1 4 "OK"
pause 5
write "ATB0+C61&C1&P1X1E0\13"
matchread 30
jump 59
!
! Next, Setup to ignore DTR
!
@LABEL 4
matchstr 1 5 "OK\13\10"
matchstr 2 59 "ERROR\13\10"
write "AT&D0\13"
matchread 30
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
!
@LABEL 5
matchclr
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATS0=0DT^1\13"
!
@LABEL 9
matchstr  1 11 "CONNECT 1200\13\10"
matchstr  2 12 "CONNECT 2400\13\10"
matchstr  3 50 "NO CARRIER\13\10"
matchstr  4 50 "ERROR\13\10"
matchstr  5 52 "NO DIALTONE\13\10"
matchstr  6 53 "BUSY\13\10"
matchstr  7 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
serreset 1200, 0, 8, 1
jump 16
!
@LABEL 12
note "Communicating at 2400 bps." 2
serreset 2400, 0, 8, 1
jump 16
!
@LABEL 16
ifANSWER 17
pause 30
@LABEL 17
exit 0
!
@LABEL 30
pause 5
write "ATS0=2\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  50 "NO CARRIER\13\10"
matchstr 5  50 "ERROR\13\10"
matchstr 6  52 "NO DIALTONE\13\10"
matchstr 7  53 "BUSY\13\10"
matchstr 8  54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
write "ATH0\13"
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 64 "ERROR\13\10"
matchread 15
inctries
iftries 3 64
! no response, try escape sequence
pause 10
matchclr
matchstr 1 62 "OK\13\10"
write "+++"
matchread 18
! No response from modem, toggle DTR
!
DTRClear
pause 10
DTRSet
jump 61
!
@LABEL 62
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
write "ATH0\13"
matchread 50
jump 61
!
@LABEL 63
pause 45
flush
!
! Recall the factory settings
!
@LABEL 64
matchclr
matchstr 1 65 "OK\13\10"
write "AT&F\13"
matchread 30
!
@LABEL 65
matchstr 1 66 "OK\13\10"
write "ATS0=0\13"
matchread 30
!
@LABEL 66
exit 0